Virtual Private Cloud:VPC and vSwitch

Console

API

Unlike creating a VPC in the console, the CreateVpc operation only creates an empty VPC. You must call the CreateVSwitch operation to create a vSwitch.

• Call CreateVpc and CreateVSwitch in sequence.

• After a VPC is created, modify the CidrBlock parameter of the ModifyVpcAttribute operation to enlarge or shrink the original IPv4 CIDR block. When shrinking it, make sure no active resources are using IPs outside the new CIDR block.

• You cannot modify the IPv4 CIDR block of a vSwitch.

• Call DeleteVSwitch and DeleteVpc in sequence to delete a vSwitch and a VPC.

  1. Make sure the vSwitch is not shared and not attached to a custom route table or network ACL, and that all cloud resources in the vSwitch have been released.

  2. Make sure that all resources in the VPC have been released and the VPC is not associated with network services such as Cloud Enterprise Network (CEN).

Terraform

Resources: alicloud_vpc, alicloud_vswitch

Data Sources: alicloud_zones

# Specify the region where the VPC is created
provider "alicloud" {
  region = "cn-hangzhou"
}

# Automatically get a list of zones where vSwitches can be created based on data sources
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Query zones where vSwitches can be created
  # available_instance_type = "ecs.g7.large"  # Query zones where ECS instances can be created
  # available_resource_creation = "slb"  # Query zones where SLB instances can be created
}

# Create a VPC 
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" # Specify the CIDR block 
}

# Create a vSwitch 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # Specify the CIDR block 
  vpc_id       = alicloud_vpc.example_vpc.id                       # Specify the ID of the VPC to which the vSwitch belongs 
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # Specify the vSwitch zone
}

Console

API

• When you create a VPC and a vSwitch, set the EnableIPv6 parameter of CreateVpc and CreateVSwitch to enable or disable IPv6.

• For existing VPCs and vSwitches, set the EnableIPv6 parameter of ModifyVpcAttribute and ModifyVSwitchAttribute to enable or disable IPv6.

Terraform

Resources: alicloud_vpc, alicloud_vswitch

Data Sources: alicloud_zones

# Specify the region where the VPC is created
provider "alicloud" {
  region = "cn-hangzhou"
}

# Automatically obtain a list of zones where vSwitches can be created based on data sources
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Query zones where vSwitches can be created in the VPC
  # available_instance_type = "ecs.g7.large"  # Query zones where ECS instances can be created in the VPC
  # available_resource_creation = "slb"  # Query zones where SLB instances can be created in the VPC
}

# Create a dual-stack VPC 
resource "alicloud_vpc" "example_vpc" {
  vpc_name    = "example_vpc_name"
  cidr_block  = "10.0.0.0/16"
  enable_ipv6 = true  # Enable IPv6, false to disable IPv6
  ipv6_isp    = "BGP" # Specify the IPv6 CIDR block type
}

# Create a dual-stack vSwitch 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name         = "example_vswitch_name"
  cidr_block           = "10.0.0.0/24"
  vpc_id               = alicloud_vpc.example_vpc.id
  zone_id              = data.alicloud_zones.available_zones.zones.0.id
  enable_ipv6          = true # Enable IPv6, false to disable IPv6
  ipv6_cidr_block_mask = 1    # Specify the last 8 bits of the vSwitch IPv6 CIDR block 
} 

Console

API

• Call AssociateVpcCidrBlock to add a secondary CIDR block.

• Call UnassociateVpcCidrBlock to delete a secondary CIDR block.

Terraform

Terraform currently supports only IPv4 secondary CIDR blocks.

Resources: alicloud_vpc_ipv4_cidr_block

# Specify the region where the VPC is created
provider "alicloud" {
  region = "cn-hangzhou"
}

# Specify the VPC ID
variable "vpc_id" {
  default = "vpc-xxx" # Replace with the actual VPC ID
}

# Create a secondary CIDR block in the VPC
resource "alicloud_vpc_ipv4_cidr_block" "example_secondary_cidr_block" {
  vpc_id               = var.vpc_id
  secondary_cidr_block = "192.168.0.0/16" # Specify the secondary CIDR block
}

Console

API

• Call CreateVSwitchCidrReservation to create a reserved CIDR block.

• Call GetVSwitchCidrReservationUsage to view occupied IPs.

• Call DeleteVSwitchCidrReservation to delete a reserved CIDR block.

Terraform

Resources: alicloud_vpc_vswitch_cidr_reservation

# Specify the region where the VPC is created
provider "alicloud" {
  region = "cn-hangzhou" # The region where the resource is located
}

# Specify the vSwitch ID
variable "vsw_id" {
  default = "vsw-xxx" # Replace with the actual vSwitch ID
}

# Create a reserved CIDR block
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # Specify the reserved CIDR block 
}

Console

Go to the Create VPC page in the VPC console, use IPv4 CIDR Block Assigned by IPAM, select an IPAM pool, and configure the subnet mask to allocate a CIDR block from the IPAM pool.

After configuring the subnet mask, the system automatically allocates the first available CIDR block within the specified subnet mask range. You can also adjust the IPv4 CIDR block within the provisioned CIDR block in the IPAM pool.

Before creating a VPC, make sure that you have created IPAM and IPAM pools on the IPAM console.

API

• If you have already created an IPAM pool, specify the IPAM pool by passing the Ipv4IpamPoolId parameter when you call CreateVpc, and pass the Ipv4CidrMask parameter to specify the subnet mask to allocate an address from the IPAM pool as the CIDR block of the new VPC. You can also pass the CidrBlock parameter to specify the VPC CIDR block, instead of automatically allocating a CIDR block by specifying the subnet mask.

• If you have not created an IPAM pool, call the following API operations in sequence to create one, and create a VPC as described above.

  1. OpenVpcIpamService - Activate IPAM

  2. CreateIpam - Create an IPAM instance

  3. CreateIpamPool - Create an IPAM pool

  4. AddIpamPoolCidr - Provision a CIDR block to an IPAM pool

Terraform

Resources: vpc_ipam_ipam, alicloud_vpc_ipam_ipam_pool, alicloud_vpc_ipam_ipam_pool_cidr, alicloud_vpc

# Specify the region where IPAM, IPAM pool, and VPC are created
provider "alicloud" {
  region = "cn-hangzhou"
}

# Create IPAM
resource "alicloud_vpc_ipam_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # Specify the effective region of IPAM
}

# Create an IPAM address pool
resource "alicloud_vpc_ipam_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam_ipam.example_ipam.private_default_scope_id # Specify the scope of the IPAM pool
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam_ipam.example_ipam.region_id # Specify the effective region of the IPAM pool
  ip_version     = "IPv4"                                     # Specify the version of the IPAM pool
}

# Allocate a CIDR block to the IPAM address pool
resource "alicloud_vpc_ipam_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # Specify the CIDR block
  ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Specify the ID of the IPAM pool
}

# Create a VPC
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Specify the ID of the IPAM pool
  ipv4_cidr_mask    = 24                                                 # IPv4 subnet mask
}